Obiectul String

Termenul de sir (string) desemneaza orice cuvant, text, fraze, sau un singur caracter, puse intre ghilimele (simple sau duble).
Sirurile pot contine numere, caractere speciale, spatii; in general orice caracter de la tastatura.
ActionScript 3 contine proprietati si metode (functii) speciale pentru lucru cu siruri, prin care se pot face diferite operatii de manipulare a sirurilor, cautare in ele, conversie.
Dupa cum totul in ActionScript 3 e vazut ca obiect, inclusiv sirurile, cand este definit un text, de ex.: "Site marplo.net", se creaza o instanta la clasa String.

1. Ghilimele si secvente escape

O variabila care stocheaza in ea date de tip String (sir) se poate defini cu oricare din urmatoarele forme:
var nume_var:String = "sirul";
var nume_var:String = new String("Sirul");
var nume_var:String = String("Sirul");
- Ghilimelele (pot fi simple sau duble) indica faptul ca textul din ele trebuie interpretat ca tip String (sir).
- De obicei se folosesc ghilimele duble, dar la fel e de preferat si simple, mai ales cand in textul respectiv sunt adaugate ghilimele duble ca parte din text. Si invers, daca textul respectiv contine ghilimele simple, e de preferat sa fie incadrat intre ghilimele duble.
De exemplu:
var sir1:String = "Tutoriale 'Flash' marplo.net";
var sir2:String = 'Tutoriale "Flash" marplo.net';
• Ca reguli generale:
- Tipul de ghilimele care incepe sirul trebuie sa fie folosit si la sfarsitul lui.
- Daca in text sunt ghilimele de acelasi tip cu cele folosite la inceputul si sfarsitul sirului, cele din text trebuie precedate de caracterul backslash (\) "escape". Astfel programul recunoaste ca acele ghilimele sunt parte din text si nu pt. sintaxa de creare a sirului.
De exemplu:
var sir1:String = "Tutoriale \"Flash\" marplo.net";
var sir2:String = 'Tutoriale \'Flash\' marplo.net';
• Secventele escape sunt grupuri de caractere formate din backslash si alt caracter, care astfel unite indeplinesc un rol special.
Secventele escape folosite sunt:

\b - caracter backspace
\f - avanseaza o pagina (rar folosit)
\n - linie noua. Adauga un rand nou
\r - la fel ca '\n', adauga un rand nou, dar aduce cursoru inapoi la inceputul liniei
\t - caracter Tab
\unnnn - adauga un caracter ce are un cod Unicode format din 4 numere hexadecimal. De ex., codul "\u0278" adauga caracterul 'ɸ'
\xnn - adauga un caracter format din 2 numere hexadecimal, codul ASCII. De ex., codul "/x25" adauga caracterul '%'
\' - ghilimele simple (')
\" - ghilimele duble (")
\\ - backslash (\)

- Unirea mai multor siruri intr-un singur sir se face cu caracterul '+'
Exemplu:

  var sir1:String = ' Jocuri ';
  var sir2:String = 'Anime';
  var sir3:String = 'Cursuri'+ sir1+ sir2;
  trace(sir3);             // Cursuri Jocuri Anime

2. Proprietati si Metode obiect String

Obiectul String are o singura proprietate, si anume length. Aceasta returneaza numarul de caractere din sir.
Exemplu:

var sir:String = "Un sir";
trace(sir.length); // 6

Metode ale obiectului String sunt:

charAt(nr) - Returneaza caracterul din sir care are indexul de ordine specificat la 'nr' (primul are index 0).
- var sir:String = "Un sir";
  trace(sir.charAt(3)); // s
charCodeAt(nr) - Codul numeric Unicode al caracterului cu numarul de ordine (index) 'nr' (primul caracter are index 0).
- var sir:String = "Un sir";
  trace(sir.charCodeAt(3)); // 115
concat('sir1', 'sir2', ...) - Adauga argumentele 'sir1', 'sir2', ... sub forma de sir la sfarsitul sirului.
- var sir:String = "Test ";
  trace(sir.concat('sir1', ' sir2')); // Test sir1 sir2
fromCharCode(cod1, cod2) - Returneaza un sir compus din caracterele echivalente codurilor Unicode 'cod1', 'cod2', ....
- trace(String.fromCharCode(115, 118)); // sv
indexOf('sub_sir', nr) - Returneaza prima pozitie a lui 'sub_sir' intr-un sir, incepand cautarea de la index 'nr' ('nr' e optional, daca nu e adaugat, se considera 0). Daca 'sub_sir' ne se afla in sirul la care e aplicata, returneaza -1.
- var sir:String = "Tutoriale";
  trace(sir.indexOf('tor')); // 2
lastIndexOf('sub_sir', nr) - Similar cu "indexOf()", dar face cautarea de la dreapta la stanga. Returneaza ultima pozitie a lui 'sub_sir' intr-un sir, incepand cautarea, spre stanga, de la index 'nr' ('nr' e optional, daca nu e augat, cautarea incepe de la ultimul caracter).
- var sir:String = "Tutoriale, cursuri online";
  trace(sir.lastIndexOf('ri')); // 16
match('sablon') - Returneaza un Array cu toate partile din sir care se potrivesc sablonului specificat la "sablon", acesta poate fi un sir, o expresie regulata RegExp sau un obiect (care va fi convertit in sir).
- var sir:String = "Tutoriale, tutor, cursuri";
  var exp:RegExp = /tu[a-z]+/gi;
  trace(sir.match(exp)); // Tutoriale,tutor
replace('sablon', 'repl') - Inlocuieste "sablon" (sir, RegExp) gasit in sir cu "repl".
- var sir:String = "Tutoriale, tutor, cursuri";
  var exp:RegExp = /tu[a-z]+/gi;
  trace(sir.replace(exp, 'Lectii')); // Lectii, Lectii, cursuri
search('sablon') - Returneaza prima pozitie a lui "sablon" (sir, RegExp) gasita in sir. Daca "sablon" nu e gasit, returneaza -1.
- var sir:String = "Tutoriale, tutor, cursuri";
  var exp:RegExp = /r[is]/i;
  trace(sir.search(exp)); // 4
slice(startIndex, endIndex) - Returneaza sub-sirul care incepe de la caracterul cu index "startIndex" (inclusiv) pana la caracterul cu index "endIndex" (fara el). Similara e si functia substring(startIndex, endIndex). Diferenta e ca "slice()" poate folosi si valori negative, dar "substring()" nu.
- var sir:String = "Curs gratuit online";
  trace(sir.slice(5, 12)); // gratuit
split('sep') - Transforma sirul in Array, cu elemente obtinute din sub-sirurile delimitate de "sep".
- var sir:String = "Curs-gratuit-online";
  trace(sir.split('-')); // Curs,gratuit,online
substr(startIndex, lun) - Obtine sub-sirul care incepe de la caracterul cu idex 'startIndex' pana la lungimea data la 'lun'.
- var sir:String = "https://marplo.net";
  trace(sir.substr(11, 6)); // marplo
toLowerCase() - Returneaza o copie a sirului, cu toate caracterele mici; fara sa afecteze sirul original.
- var sir:String = "Tutoriale, Cursuri ONLINE";
  trace(sir.toLowerCase()); // tutoriale, cursuri online
toUpperCase() - Returneaza o copie a sirului, cu toate caracterele mari (majuscule); fara sa afecteze sirul original.
- var sir:String = "Tutoriale, Cursuri ONLINE";
  trace(sir.toUpperCase()); // TUTORIALE, CURSURI ONLINE
toString() - Transforma in sir obiectul la care e aplicata.
- var nr:int = 7;
  var sir:String = '8';
  trace(nr.toString()+ sir); // 78 (sau String(nr)+ sir )
Number('sir') - Transforma "sir" in Numar.
- var nr:int = 7;
  var sir:String = '8';
  trace(nr+ Number(sir)); // 15

<<-Functii - Utilizare avansata -- Obiect Number si Math ..->>

Un Test simplu in fiecare zi

HTML

CSS

JavaScript

PHP-MySQL

Engleza

Spaniola

Care tag e folosit pentru a adauga liste cu definitii in element <dl>?

<dl>
 <dt>HTML</dt>
  <dd> - Hyper Text Markup Language</dd>
  <dd> - Limbaj de cod pentru pagini web</dd>
</dl>

Care proprietate CSS poate sa ascunda un element in pagina, lasand spatiu gol in locul lui?

display position visibility

#id {
  visibility: hidden;
}

Indicati evenimentul declansat cand se apasa clic pe un obiect in pagina.

onclick onmouseover onfocus

document.getElementById("id").onclick = function(){
  alert("http://www.MarPlo.net/");
}

Indicati variabila PHP ce contine datele din $_GET, $_POST si $_COOKIE.

$_SESSION $_GET $_REQUEST

if(isset($_REQUEST["id"])) {
  echo $_REQUEST["id"];
}

Care din urmatoarele cuvinte reprezinta un Verb?

lighting believe path

I believe in my path.
- Eu cred in calea mea.

Care din urmatoarele cuvinte reprezinta un Verb?

creer camino iluminación

creer = a crede; camino = cale /drum; iluminación = iluminare

Obiectul String - Siruri

Curs Flash